home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
90xx
/
9008a.d64
/
leseroutine 2
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
37 lines
10 REM SPEEDLESEROUTINE FUER ALLE SPUREN
20 REM (C) 1986 BY KLAUS RACZEK
30 :
40 DIM R(52): REM FELD FUER LESEROUTINE
50 OPEN1,8,15,"I":REM FEHLERKANAL OEFFNEN UND INITIALISIEREN
60 PRINT#1,"M-W"CHR$(106)CHR$(0)CHR$(1)CHR$(133): REM BEI ERROR NICHT KLAPPERN
70 FORI=0TO52
80 READ R(I): REM MASCHINENPROGRAMM IN
90 NEXT I: REM FELD R() EINLESEN
100 PRINT"[147]EINLESEN EINES SEKTORS"
110 INPUT"WELCHE SPUR (1-40)";SP:R(34)=SP
120 INPUT"WELCHER SEKTOR";SE:R(38)=SE
130 INPUT"HEADERSPEED";HS:R(6)=HS*32
140 INPUT"BLOCKSPEED";BS:R(23)=BS*32
150 INPUT"WELCHE ID (ODER RETURN)";ID$
160 IFID$<>""THENPRINT#1,"M-W"CHR$(18)CHR$(0)CHR$(2)ID$
170 FORI=0TO52
180 PRINT#1,"M-W"CHR$(I)CHR$(4)CHR$(1)CHR$(R(I)):REM PROGRAMM IN PUFFER SCHREIBE
190 NEXT I
200 PRINT#1,"M-E"CHR$(33)CHR$(4):REM PROGRAMM IN PUFFER AUSFUEHREN
210 INPUT#1,A,B$,C,D:PRINT:PRINTA;B$;C;D:REM FEHLERKANAL LESEN UND ZEIGEN
220 FORI=1TO3000:NEXT
230 :
240 DATA173,0,28,41,159,9,0,141,0,28,169,3,133,49,32,16,245,173,0,28,41,159
250 DATA9,0,141,0,28,32,86,245,76,212,244,169,24,133,8,169,0,133,9,162,1,134
260 DATA249,169,224,32,125,213,76,153,213
270 :
280 PRINT"ANZEIGEN DES BLOCKINHALTS":FORI=1TO2000:NEXT
290 REM 256 BYTES
300 :
310 FORI=0TO255STEP16:PRINT"[147]BYTE BYTE BYTE"
320 PRINT"NUMMER DEZIMAL ASCII":FORJ=0TO15
330 PRINT#1,"M-R"CHR$(I+J)CHR$(3)
340 GET#1,A$:A=ASC(A$+CHR$(0)):REM EINE BYTE LESEN
350 PRINT""I+J,A,A$"":REM AUSGEBEN: BYTENUMMER, ASC-WERT, ASCII-ZEICHEN
360 NEXT:PRINT"TASTE":POKE198,0:WAIT198,1:NEXT